$ verify = 'F$VERIFY(0)'
$ GOTO L1$
$!
$! VMSLBRSQU.JOB
$!
$! Batch job run to compress (or attempt to) all VAX/VMS native mode
$! help, macro, object and text libraries in various areas on the system
$! disk.
$!
$! Modifications:
$!  17-Oct-83	FJN	Created from RSXLBRSQU.JOB
$!  30-Dec-83	FJN	Also look at libraries in FERMI$LIB, DTR$LIBRARY and
$!			FERMI$HELP
$!  05-Mar-84	FJN	Provided controls, just do .HLB and .TLB's for now
$!  02-Apr-84	FJN	Fix as SQUEEZE takes only file spec. parameter
$!  06-May-84	FJN	Do all library types after making save disk
$!=============================================================================
$L1$:
$ SQUEEZE := @SYS$MGR_UTIL:VMSLBRSQU
$!
$! Control which library types are examined and squeezed.
$!
$ skip_help = "NO"			!Help (.HLB) libraries
$ skip_text = "NO"			!Text (.TLB) libraries
$ skip_macro = "NO"			!Macro (.MLB) libraries
$ skip_object = "NO"			!Object and image (.OLB) libraries
$!
$! Do all the HELP libraries in SYS$HELP:.
$!
$ IF skip_help THEN $ GOTO HLB_DONE
$HLB_LOOP:
$ file = F$SEARCH("SYS$HELP:*.HLB")
$ IF file .EQS. "" THEN $ GOTO HLB_DONE
$ SQUEEZE  'file'
$ GOTO HLB_LOOP
$HLB_DONE:
$!
$! Do all the HELP libraries in FERMI$HELP:.
$!
$ IF skip_help THEN $ GOTO FHLB_DONE
$ IF F$LOGICAL("FERMI$HELP") .EQS. "" THEN $ GOTO FHLB_DONE
$FHLB_LOOP:
$ file = F$SEARCH("FERMI$HELP:*.HLB")
$ IF file .EQS. "" THEN $ GOTO FHLB_DONE
$ SQUEEZE  'file'
$ GOTO FHLB_LOOP
$FHLB_DONE:
$!
$! Now do all the text libraries in SYS$LIBRARY:
$!
$ IF skip_text THEN $ GOTO TLB_DONE
$TLB_LOOP:
$ file = F$SEARCH("SYS$LIBRARY:*.TLB")
$ IF file .EQS. "" THEN $ GOTO TLB_DONE
$ SQUEEZE  'file'
$ GOTO TLB_LOOP
$TLB_DONE:
$!
$! Now do all the text libraries in FERMI$LIB:
$!
$ IF skip_text THEN $ GOTO FTLB_DONE
$ IF F$LOGICAL("FERMI$LIB") .EQS. "" THEN $ GOTO FTLB_DONE
$FTLB_LOOP:
$ file = F$SEARCH("FERMI$LIB:*.TLB")
$ IF file .EQS. "" THEN $ GOTO FTLB_DONE
$ SQUEEZE  'file'
$ GOTO FTLB_LOOP
$FTLB_DONE:
$!
$! Now do all the macro libraries in SYS$LIBRARY: except for RMSMAC (RSX-11M
$! RMS macro library).
$!
$ IF skip_macro THEN $ GOTO MLB_DONE
$MLB_LOOP:
$ file = F$SEARCH("SYS$LIBRARY:*.MLB")
$ IF file .EQS. "" THEN $ GOTO MLB_DONE
$ IF F$PARSE(file,,,"NAME") .EQS. "RMSMAC" THEN $ GOTO MLB_LOOP
$ SQUEEZE  'file'
$ GOTO MLB_LOOP
$MLB_DONE:
$!
$! Now do all the macro libraries in FERMI$LIB:
$!
$ IF skip_macro THEN $ GOTO FMLB_DONE
$ IF F$LOGICAL("FERMI$LIB") .EQS. "" THEN $ GOTO FMLB_DONE
$FMLB_LOOP:
$ file = F$SEARCH("FERMI$LIB:*.MLB")
$ IF file .EQS. "" THEN $ GOTO FMLB_DONE
$ SQUEEZE  'file'
$ GOTO FMLB_LOOP
$FMLB_DONE:
$!
$! Now do all the object libraries in SYS$LIBRARY: except for the RSX-11M
$! object libraries RMSLIB.OLB, SYSLIB.OLB and F77*.OLB.
$!
$ IF skip_object THEN $ GOTO OLB_DONE
$OLB_LOOP:
$ file = F$SEARCH("SYS$LIBRARY:*.OLB")
$ IF file .EQS. "" THEN $ GOTO OLB_DONE
$ name = F$PARSE(file,,,"NAME")
$ IF name .EQS. "RMSLIB" THEN $ GOTO OLB_LOOP
$ IF name .EQS. "SYSLIB" THEN $ GOTO OLB_LOOP
$ IF F$EXTRACT(0,3,name) .EQS. "F77" THEN $ GOTO OLB_LOOP
$ SQUEEZE  'file'
$ GOTO OLB_LOOP
$OLB_DONE:
$!
$! Now do all the object libraries in FERMI$LIB:
$!
$ IF skip_object THEN $ GOTO FOLB_DONE
$ IF F$LOGICAL("FERMI$LIB") .EQS. "" THEN $ GOTO FOLB_DONE
$FOLB_LOOP:
$ file = F$SEARCH("FERMI$LIB:*.OLB")
$ IF file .EQS. "" THEN $ GOTO FOLB_DONE
$ SQUEEZE  'file'
$ GOTO FOLB_LOOP
$FOLB_DONE:
$!
$! Now do all the macro libraries in DTR$LIBRARY:
$!
$ IF skip_macro THEN $ GOTO DMLB_DONE
$ IF F$LOGICAL("DTR$LIBRARY") .EQS. "" THEN $ GOTO DMLB_DONE
$DMLB_LOOP:
$ file = F$SEARCH("DTR$LIBRARY:*.MLB")
$ IF file .EQS. "" THEN $ GOTO DMLB_DONE
$ SQUEEZE  'file'
$ GOTO DMLB_LOOP
$DMLB_DONE:
$!
$! Now do all the object libraries in DTR$LIBRARY:
$!
$ IF skip_object THEN $ GOTO DOLB_DONE
$ IF F$LOGICAL("DTR$LIBRARY") .EQS. "" THEN $ GOTO DOLB_DONE
$DOLB_LOOP:
$ file = F$SEARCH("DTR$LIBRARY:*.OLB")
$ IF file .EQS. "" THEN $ GOTO DOLB_DONE
$ SQUEEZE  'file'
$ GOTO DOLB_LOOP
$DOLB_DONE:
$!
$! Now do some individual libraries in various places.
$!
$! Do SYS$MESSAGE:SYSMSG.TLB
$!
$ IF (.NOT. skip_text) .AND. -
     (F$SEARCH("SYS$MESSAGE:SYSMSG.TLB") .NES. "") THEN  -
$	SQUEEZE  SYS$MESSAGE:SYSMSG.TLB
$!
$! Do SYS_OPERATOR:OPRHELP.HLB
$!
$ IF (.NOT. skip_help) .AND. -
     (F$LOGICAL("SYS_OPERATOR") .NES. "") .AND. -
     (F$SEARCH("SYS_OPERATOR:OPRHELP.HLB") .NES. "") THEN  -
$	SQUEEZE  SYS_OPERATOR:OPRHELP.HLB
$!
$ EXIT