$ VERIFY = 'F$VERIFY("NO")'
$ ON CONTROL_Y THEN EXIT %X10000004
$!-----------------------------------------------------------------------------
$!   OFFLOAD.PUT - The function of this routine is to write each file in a
$!	list of file specifications to the specified device.
$!	Each specification is seperated by a ",-" including a trailing ",-".
$!
$!	P1 - contains the logical name of the device to output to.
$!	P2 - contains any leading characters to go before file on output.
$!	P3 - contains the list of file specifications
$!-----------------------------------------------------------------------------
$!
$!    Display the files already selected.
$!
$	W := WRITE 'P1'
$	TMP := "''P3'"
$	P = 'F$LENGTH(TMP)' - 2
$	IF P .GE. 2 THEN TMP[P,2]:=" -"
$	DO_OFFLOAD_DISP:
$	    IF TMP .EQS. "" THEN GOTO ENDDO_OFFLOAD_DISP
$	    L = 'F$LOCATE(",-",TMP)' + 2
$	    FILE := "''P2'''F$EXTRACT(0,L,TMP)'"
$	    TMP := "''F$EXTRACT(L,255,TMP)'"
$	    W FILE
$	    GOTO DO_OFFLOAD_DISP
$	ENDDO_OFFLOAD_DISP:
$!
$!    Exit.
$!
$ EXIT:
$	IF VERIFY THEN SET VERIFY	!'F$VERIFY("NO")'