.TITLE  SETACC - SET ACCOUNT NAME
;Originally written by Bob Conti (who'd probably deny it!)
;Rev. 7/19/82 A. Sorrell - Mod for V3 to stuff account into JIB
;                          as well as control region. See V3.0
;                          microfiche #129 G-10
;
;It is necessary to use a LINK ...,SETACC,SYS$SYSTEM:SYS.STB/SELECTIVE
;to correctly resolve the value for the CTL$T_ parameters needed.
;       CTL$T_ACCOUNT = ^X7FFEFEA8              ;V3 value - use LINK as above
;
        .LIBRARY /SYS$LIBRARY:LIB.MLB/
        $JIBDEF
        $PCBDEF
        ACC=    4                               ;OFFSET TO ACCOUNT NAME
 
        .ENTRY  SETACC,^M<R2,R3,R4,R5,R6,R7>
        MOVAW   @ACC(AP),R6                     ;Get ACCOUNT name
        $CMKRNL_S       STUFFIT                 ;Get to where i can do the STUFF
        RET                                     ;Return when done
;
; Code to actually stuff the account number into process header
; and JIB.
;
STUFFIT:.WORD   ^M<>
        MOVC3   #8,(R6),CTL$T_ACCOUNT           ;Set ACCOUNT name in control reg
        MOVL    CTL$GL_PCB,R0                   ;
        MOVL    PCB$L_JIB(R0),R7                ;Get address of JIB
        MOVC3   #8,(R6),JIB$T_ACCOUNT(R7)       ;Stuff ACCOUNT in JIB as well
        MOVL    #SS$_NORMAL,R0                  ;Set successful completion
        RET                                     ;Return from CMKRNL
        .END