!
!	ALEDTINI.EDT  An EDT Editor initialization file
!
!	Copyright (c) 1985 by  	W. J. Haas, Jr.
!				M. E. Nieland
!				M. Frisk
!		Ames Laboratory
!		Iowa State University
!		Ames, Iowa  50011
!
!	This file defines many keys that can be used while in
!	the nokeypad change mode of EDT.  These key definitions
!	enhance EDT by making certain functions faster.  An associated
!	file is EDTINIHLP.EDT.
!
!	This initialization file contains definitions compatible
!	with VAX/VMS Version 4.0 and contains a definition using the
!	XLATE function for use with the Ames Lab extended EDT Editor,
!	EDT.FOR.  The latter was written by M. Edward Nieland, to create 
!	subprocesses to do DCL commands through the XLATE command.
!
!+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
!    SCREEN WIDTH MACROS
!+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
DEFINE MACRO WIDTH_132
I=WIDTH_132
DEFINE KEY GOLD W AS "EXT WIDTH_80."
SET SCREEN 132
SET WRAP 131
^Z
!
DEFINE MACRO WIDTH_80
I=WIDTH_80
DEFINE KEY GOLD W AS "EXT WIDTH_132."
SET SCREEN 80 
SET WRAP 79
^Z
!+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
!    SCREEN TRUNCATE MACROS
!+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
DEFINE MACRO TRUNCATE
I=TRUNCATE
DEFINE KEY GOLD CONTROL W AS "EXT NO_TRUNCATE."
SET TRUNCATE
DEFINE KEY GOLD 14 AS "5(SHL)40C."
DEFINE KEY GOLD 15 AS "5(SHR)-40C."
^Z
!
DEFINE MACRO NO_TRUNCATE
I=NO_TRUNCATE
DEFINE KEY GOLD CONTROL W AS "EXT TRUNCATE."
SET NOTRUNCATE
DEFINE KEY GOLD 15 AS "BL."
DEFINE KEY GOLD 14 AS "EL."
^Z
!+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
!	WORD DELIMITER MACROS
!+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
DEFINE MACRO DELIMITERS_PROGRAMMING
FIND=DELIMITERS_PROGRAMMING
I
DEFINE KEY GOLD D AS "EXT DELIMITERS_WORD_PROCESSING."
^Z
C; ISE EN WO '^Z 9ASC 10ASC 11ASC 12ASC 13ASC 27ASC I ()[],-+#/='^Z EX
!
DEFINE MACRO DELIMITERS_WORD_PROCESSING
FIND=DELIMITERS_WORD_PROCESSING
I
DEFINE KEY GOLD D AS "EXT DELIMITERS_PROGRAMMING."
^Z
C; ISE EN WO '^Z 9ASC 10ASC 11ASC 12ASC 13ASC 27ASC I ,'^Z EX
!+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
!   DEFINE BUFFERS FOR RULER, DCL_COMMENT_LINE, FORTRAN_COMMENT_LINE
!+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
FIND=RULER
I
....v....1....v....2....v....3....v....4....v....5....v....6....v....7....v....
^Z
FIND=DCL_COMMENT_LINE
I
$!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
^Z
FIND=FORTRAN_COMMENT_LINE
I
C***********************************************************************
^Z
!+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
!   DEFINE MACRO FOR CONTROL_KEY_HELP TABLE
!+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
DEFINE MACRO CONTROL_KEY_HELP
FIND=CONTROL_KEY_HELP
I
FIND = HELP
DEFINE KEY GOLD 10 AS "EXT =HELP 22."
DEFINE KEY GOLD CONTROL M AS "EXT FIND LAST."
INCLUDE EDT_LIBRARY:EDTINIHLP.EDT
^Z
FIND =MAIN
FIND BEGIN
SET WRAP 79
SET NONUMBER
SET TRUNCATE
SET MODE C
DEFINE KEY GOLD DELETE AS "EXT CLEAR ?'Delete contents of what buffer ? '."
!DEFINE KEY 3 AS "(I_^Z 8ASC +C)."! UNDERLINE CHARACTER COMMAND!
DEFINE KEY 3 AS "-W."
DEFINE KEY GOLD $ AS "PASTE=DCL_COMMENT_LINE L."
DEFINE KEY GOLD * AS "PASTE=FORTRAN_COMMENT_LINE L."
DEFINE KEY GOLD 12 AS "(-22V)."
DEFINE KEY GOLD 13 AS "(22V)."
DEFINE KEY GOLD 15 AS "BL."
DEFINE KEY GOLD 14 AS "EL."
DEFINE KEY GOLD 10 AS "EXT CONTROL_KEY_HELP."
DEF K GOLD A AS "EXT CO SEL TO=?'Copy to end of what buffer ? ' END; F L."
DEFINE KEY GOLD B AS "EXT FIND=?'Switch to what buffer ? '.."
DEFINE KEY GOLD C AS "EXT COPY SELECT TO=?'Copy to what buffer ? '; FIND LAST."
DEFINE KEY GOLD D AS "EXT DELIMITERS_WORD_PROCESSING."
DEFINE KEY GOLD E AS "EXT SET SEARCH EXACT."
DEFINE KEY GOLD F AS "(SEL PAR FILLSR)."
DEFINE KEY GOLD G AS "EXT SET SEARCH GENERAL."
DEFINE KEY GOLD H AS "EXT HELP ?'Help for what topic: '."
DEFINE KEY GOLD I AS "EXT INCLUDE ?'Name of file to be included ? '."
DEFINE KEY GOLD K AS "CUTSR=?'Cut to what buffer ? '."
DEFINE KEY GOLD M AS "EXT F=MAIN.."
DEFINE KEY GOLD N AS "EXT SET WRAP 79."
DEFINE KEY GOLD P AS "PASTE=?'Paste from what buffer ? '."
DEFINE KEY GOLD O AS "EXT WRITE ?'Name of File to be stored ? '."
DEFINE KEY GOLD Q AS "QUIT."
DEFINE KEY GOLD R AS "PASTE=RULER L."
DEFINE KEY GOLD S AS "EXT SHOW BUFFER."
DEFINE KEY GOLD T AS "EXT SET WRAP 65."
DEFINE KEY GOLD X AS "EXT EXIT."
DEFINE KEY GOLD W AS "EXT WIDTH_132."
DEFINE KEY GOLD CONTROL D AS "XLATE?'DCL Command: '^Z."
DEFINE KEY GOLD CONTROL E AS "EXT SET HELP EDTHELP.HLB."
DEFINE KEY GOLD CONTROL F AS "EXT SET HELP FORHELP.HLB."
DEFINE KEY GOLD CONTROL H AS "EXT SET HELP HELPLIB.HLB."
DEFINE KEY GOLD CONTROL V AS "EXT SHOW HELP."
DEFINE KEY GOLD CONTROL W AS "EXT TRUNCATE."
!SET COMMAND SYS$LOGIN:EDTINI.EDT
!SET COMMAND EDTINI.EDT