$ !SET VERIFY
$ SET ON
$ !--------------------------------------------------------------------------
$ !
$ !	    S Y S _ U T I L I T Y : W A T C H D O G . B L D
$ !
$ !	Purpose:
$ ! 		Compiles and Links Watchdog Program
$ !
$ !	Original:	G. H. Walrod III
$ !	Modification:
$ !			Add Multi Version Section some User
$ !			have the Option.
$ !				12/06/85	George H. Walrod III
$ !
$ !--------------------------------------------------------------------------
$ WRITE SYS$OUTPUT "This Command file is used to Build WATCHDOG"
$ WRITE SYS$OUTPUT " "
$ !
$ !	Inquire VMS Version Number
$ !
$ INQUIRE version -
     "Are you building WATCHDOG for VMS versions lower than 4.0(def: N) "
$ IF version .EQS. "" THEN version = "N"
$ WRITE SYS$OUTPUT " "
$ !
$ !	Inquire for Recompile of WATCHDOG
$ !
$ WRITE SYS$OUTPUT -
   "*** ALL PROGRAM WILL BE RELINKED ***"
$ INQUIRE compile -
     "Do you want to recompile WATCHDOG (FORTRAN and MACRO REQUIRED)(def: Y) "
$ IF compile .EQS. "" THEN compile = "Y"
$ WRITE SYS$OUTPUT " "
$ IF F$EXTRACT(0,1,compile) .NES. "Y" THEN GOTO SETOBJ_PROGRAM
$ !
$ !	Inquire for Recompile with Debug
$ !
$ INQUIRE debugger -
     "DO YOU NEED THE DEBUGGER(def: N) "
$ IF debugger .EQS. "" THEN debugger = "N"
$ WRITE SYS$OUTPUT " "
$ debug_link  = "/NOTRACEBACK"
$ macro_debug = " "
$ debug_comp  = " "
$ IF F$EXTRACT(0,1,debugger) .NES. "Y" THEN GOTO SETSRC_PROGRAM
$ debug_comp  = "/D_LINES/DEBUG"
$ macro_debug = "/DEBUG"
$ debug_link  = "/DEBUG/TRACEBACK"
$ !
$ !	Set Version of Watchdog Source
$ !
$SETSRC_PROGRAM:
$ WRITE SYS$OUTPUT "SETTING VMS VERSION FOR COMPILE"
$ IF version .EQS. "N" THEN GOTO SETSRC_4X
$ COPY WATCHDOG.F3X WATCHDOG.FOR
$ GOTO COMPILE_PROGRAM
$SETSRC_4X:
$ COPY WATCHDOG.F4X WATCHDOG.FOR
$ !
$ !	Compile WATCHDOG.FOR
$ !
$COMPILE_PROGRAM:
$ WRITE SYS$OUTPUT "Recompiling Watchdog"
$ FORTRAN/LIST/CROSS/CONTIN=99 WATCHDOG.FOR 'debug_comp'
$ !
$ !	Assemble WATCHSYM.MAR
$ !
$ WRITE SYS$OUTPUT "Assembling Watchsym Macro"
$ MACRO WATCHSYM.MAR
$ IF VERSION .NES. "N" THEN GOTO LINK_PROGRAM
$ !
$ !	Assemble GETPID.MAR
$ !
$ WRITE SYS$OUTPUT "Assembling Getpid Macro For 4.X"
$ MACRO GETPID.MAR 'macro_debug'
$ GOTO LINK_PROGRAM
$ !
$ !	Set Version of WATCHDOG Object
$ !
$SETOBJ_PROGRAM:
$ WRITE SYS$OUTPUT "SETTING VMS VERSION FOR LINK"
$ IF VERSION .EQS. "N" THEN GOTO SETOBJ_4X
$ COPY WATCHDOG.O3X WATCHDOG.OBJ
$ GOTO LINK_PROGRAM
$SETOBJ_4X:
$ COPY WATCHDOG.O4X WATCHDOG.OBJ
$ !
$ !	LINK WATCHDOG
$ !
$LINK_PROGRAM:
$ WRITE SYS$OUTPUT "Linking Watchdog"
$ getpid_macro = ", GETPID, SYS$SYSTEM:SYS.STB/SELECTIVE"
$ IF VERSION .NES. "N" THEN getpid_macro = " "
$ LINK WATCHDOG, WATCHSYM/SELECTIVE 'getpid_macro' 'debug_link'
$ !
$ !	EXITING
$ !
$ WRITE SYS$OUTPUT "Complete"
$ EXIT