Module  MAG_DIRECTIVES


Define Verb  READ , Routine COMMAND_IS_READ

  Parameter  P1 , Value( Required, Type=$REST_OF_LINE )

Define Verb  GET , Routine COMMAND_IS_READ

  Parameter  P1 , Value( Required, Type=$REST_OF_LINE )

Define Verb  WRITE , Routine COMMAND_IS_WRITE

  Parameter  P1 , Value( Required, Type=$REST_OF_LINE )

Define Verb  SKIP , Routine COMMAND_IS_SKIP

  Parameter  P1 , Value( Required, Type=$NUMBER )

Define Verb  REWIND , Routine COMMAND_IS_REWIND

Define Verb  SHOW , Routine COMMAND_IS_SHOW

Define Verb  HELP , Routine COMMAND_IS_HELP

  Parameter  P1 , Value( Type=$REST_OF_LINE )

Define Verb  EXIT , Routine COMMAND_IS_EXIT

Define Verb  MOUNT , Routine COMMAND_IS_MOUNT

  Parameter  P1		! P1 and P2 are the tape name and density; they can
			!  appear in either order, and either or both can
  Parameter  P2		!  be omitted.

    Qualifier  WRITE , Default

Define Verb  DISMOUNT , Routine COMMAND_IS_DISMOUNT

    Qualifier  UNLOAD , Default

Define Verb  SET

  Parameter  P1 , Value( Required, Type=SETS )

Define Syntax  SET_BLOCKSIZE , Routine SET_BLOCKSIZE

  Parameter  P1 , Value( Required )

  Parameter  P2 , Value( Required, Type=$NUMBER )

Define Syntax SET_RECORDSIZE, Routine SET_RECORDSIZE

  Parameter  P1 , Value( Required )

  Parameter  P2 , Value( Required )		! Either VARYING or a number

Define Syntax  SET_MAGTAPE, Routine SET_MAGTAPE

  Parameter  P1 , Value( Required )

  Parameter  P2 , Value( Required, Type=$DEVICE )

Define Syntax SET_COLUMNS, Routine SET_COLUMNS

  Parameter  P1 , Value( Required )

  Parameter  P2 , Value( Type=$NUMBER )		! Either both or neither of
  						!  P2 and P3 must be specified.
  Parameter  P3 , Value( Type=$NUMBER )		!  If neither are, ALL columns
  						!  are processed.
Define Syntax SET_DEFAULT, Routine SET_DEFAULT

  Parameter  P1 , Value( Required )

  Parameter  P2 , Value( Type=$FILE )		! If absent, no default is used.

Define Syntax SET_LINES, Routine SET_LINES

  Parameter  P1 , Value( Required )

  Parameter  P2 , Value( Type=$NUMBER )		! If zero or absent, all lines
						!  are processed.
Define Syntax SET_MISC, Routine SET_MISC

  Parameter  P1 , Value( Required )


Define Type  SETS , Keyword BLOCKSIZE,	 Syntax SET_BLOCKSIZE
		    Keyword RECORDSIZE,	 Syntax SET_RECORDSIZE
		    Keyword MAGTAPE,	 Syntax SET_MAGTAPE
		    Keyword TAPE,	 Syntax SET_MAGTAPE
		    Keyword COLUMNS,	 Syntax SET_COLUMNS
		    Keyword DEFAULT,	 Syntax SET_DEFAULT
		    Keyword LINES,	 Syntax SET_LINES
		    Keyword ASCII,	 Syntax SET_MISC
		    Keyword EBCDIC,	 Syntax SET_MISC
		    Keyword TRUNCATE,	 Syntax SET_MISC
		    Keyword NOTRUNCATE,	 Syntax SET_MISC
		    Keyword BYTESWAP,	 Syntax SET_MISC
		    Keyword NOBYTESWAP,	 Syntax SET_MISC
		    Keyword SPACES,	 Syntax SET_MISC
		    Keyword NOSPACES,	 Syntax SET_MISC

!
!			sgs_version = "3.0"
!