$ SET NOVERIFY
$ SET ON
$ !--------------------------------------------------------------------------
$ !
$ !	    S Y S _ U T I L I T Y : W A T C H D O G . B L D
$ !
$ !	Purpose:
$ ! 		Compiles and Links Watchdog Program
$ !
$ !	Original:	G. H. Walrod III
$ !	Modification:
$ !		V4.0-0	Add Multi Version Section so User has the
$ !			Option.
$ !				12/06/85	George H. Walrod III
$ !		V4.0-2	Made it So That Recompling is Neccessary
$ !				02/18/86	George H. Walrod III
$ !		V4.1-0	Add Exeception Routines
$ !				02/19/86	George H. Walrod III
$ !		V4.2-0	Remove V4.1 Exeception Routines and Add
$ !			Real Routines.
$ !				09/10/86	George H. Walrod III
$ !
$ !--------------------------------------------------------------------------
$ WRITE SYS$OUTPUT "This Command file is used to Build WATCHDOG"
$ WRITE SYS$OUTPUT " "
$ !
$ !	Inquire VMS Version Number
$ !
$ INQUIRE version -
     "Are you building WATCHDOG for VMS versions lower than 4.0(def: N) "
$ IF version .EQS. "" THEN version = "N"
$ WRITE SYS$OUTPUT " "
$ !
$ !	Inquire for Recompile with Debug
$ !
$ INQUIRE debugger -
     "Do you need the Debugger(def: N) "
$ IF debugger .EQS. "" THEN debugger = "N"
$ WRITE SYS$OUTPUT " "
$ debug_link  = "/NOTRACEBACK"
$ macro_debug = " "
$ debug_comp  = " "
$ IF F$EXTRACT(0,1,debugger) .NES. "Y" THEN GOTO CHECK_DLINES
$ debug_comp  = "/DEBUG/NOOPTIMIZE"
$ macro_debug = "/DEBUG"
$ debug_link  = "/DEBUG/TRACEBACK"
$ !
$ !	Inquire for Recompile with D_LINES
$ !
$CHECK_DLINES:
$ IF version .EQS. "N" THEN GOTO SETSRC_PROGRAM
$ INQUIRE dlines -
     "Do you need the D_Lines Option(def: N) "
$ IF dlines .EQS. "" THEN dlines = "N"
$ WRITE SYS$OUTPUT " "
$ IF F$EXTRACT(0,1,dlines) .NES. "Y" THEN GOTO SETSRC_PROGRAM
$ debug_comp  = "''debug_comp'/D_LINES"
$ !
$ !	Set Version of Watchdog Source
$ !
$SETSRC_PROGRAM:
$ IF version .EQS. "N" THEN GOTO SETSRC_4X
$ !
$ !	Compile WATCHDOG.FOR
$ !
$COMPILE_PROGRAM:
$ WRITE SYS$OUTPUT "Recompiling Version 3.X of Watchdog"
$ FORTRAN/LIST/CROSS/CONTIN=99 WATCHDOG.FOR 'debug_comp'
$ !
$ !	Assemble WATCHSYM.MAR
$ !
$ WRITE SYS$OUTPUT "Assembling Watchsym Macro"
$ MACRO/LIST WATCHSYM.MAR
$ LIBRARY/CREATE WATCHDOG WATCHSYM
$ !
$ !	LINK WATCHDOG
$ !
$LINK_PROGRAM:
$ WRITE SYS$OUTPUT "Linking Version 3.x Watchdog"
$ LINK/MAP WATCHDOG, WATCHDOG/INCLUDE=WATCHSYM/LIBRARY/SELECTIVE  'debug_link'
$ GOTO EXIT
$ !
$ !	Assembling V4.x WATCHDOG.MAR
$ !
$SETSRC_4X:
$ WRITE SYS$OUTPUT "Assembling 4.x Watchdog"
$ MACRO/LIST WATCHDOG.MAR 'macro_debug'
$ !
$ !	LINK WATCHDOG VERION 4.X
$ !
$LINK_PROGRAM:
$ WRITE SYS$OUTPUT "Linking Version 4.x Watchdog"
$ LINK/MAP 'debug_link' WATCHDOG
$ !
$ !	EXITING
$ !
$EXIT:
$ WRITE SYS$OUTPUT "Complete"
$ EXIT