!
!
! ***** MAP TO BOTTOM WINDOW *****
!
! This maps two windows to the screen.  It maps the specified buffer
!    to the bottom window.  The cursor is positioned in the bottom window.
!
PROCEDURE fred$map_to_bottom_window (buffer_name)
   LOCAL buffer_to_map,
	this_buffer;

   this_buffer := CURRENT_BUFFER;
   buffer_to_map := decus$find_buffer (buffer_name);
   if buffer_to_map = 0 then
      MESSAGE (FAO ("No such buffer: !AS",buffer_name));
      RETURN;
   endif;
   if buffer_to_map <> this_buffer then
      if eve$x_number_of_windows = 2 then
   	 if CURRENT_WINDOW <> eve$bottom_window then	! Tie to bottom window 
            eve_other_window;
	 endif;
         if CURRENT_BUFFER <> buffer_to_map then
            MAP (CURRENT_WINDOW, buffer_to_map);
         endif;
      else
         UNMAP (eve$main_window);
         MAP (eve$top_window, this_buffer);
         eve$set_status_line (eve$top_window);
         UPDATE (eve$top_window);
         MAP (eve$bottom_window, buffer_to_map);
         eve$set_status_line (eve$bottom_window);
         eve$x_number_of_windows := 2;
         eve$x_this_window := eve$bottom_window;
      endif;
   endif;
   eve$update_status_lines;
   POSITION (BEGINNING_OF (buffer_to_map));
ENDPROCEDURE;