$!+++ Build new NOTESplus section file
$!
$! Check if needed logicals are defined, define if not
$!
$ DEFINE_DONE := FALSE
$ temp = f$trnlnm("TPU$EVEPLUS")
$ IF TEMP .NES. "" THEN GOTO FIRST_LOGICAL_DEFINED
$ temp = f$trnlnm("SYS$UTILITY")
$ IF TEMP .EQS. "" THEN GOTO NO_LOGICAL
$ DEVICE = F$PARSE(TEMP,,,"DEVICE")
$ LOGDEF = DEVICE + "[SYSUTL.EVEPLUS]"
$ DEFINE TPU$EVEPLUS 'LOGDEF'
$ DEFINE_DONE := TRUE
$FIRST_LOGICAL_DEFINED:
$ TEMP = F$TRNLNM("TPU$LOCAL")
$ IF TEMP .NES. "" THEN GOTO LOGICAL_DEFINED
$ DEFINE TPU$LOCAL DISK_FSGPROD:[TPU]
$ DEFINE_DONE := TRUE
$LOGICAL_DEFINED:
$ IF .NOT. DEFINE_DONE THEN GOTO LOGNAM_OK
$ WRITE SYS$OUTPUT "Logical name(s) TPU$EVEPLUS or TPU$LOCAL defined:"
$ SHOW LOGICAL TPU$EVEPLUS
$ SHOW LOGICAL TPU$LOCAL
$ INQUIRE YN "Proceed with these definitions?"
$ if .not.YN then goto NO_LOGICAL
$LOGNAM_OK:
$ old_default = f$environment("default")
$ set default TPU$EVEPLUS
$ define/user sys$input sys$command
$ define/user tpusecini sys$share:notes$section.tpu$section
$ edit/tpu-
	/command=tpu$eveplus:notesplus_build -
	tpu$local:NOTESPLUS_SYSTEM.TPU
$ set default 'old_default'
$ exit
$
$NO_LOGICAL:
$ WRITE SYS$OUTPUT -
  "Unable to properly define logicals TPU$EVEPLUS and TPU$LOCAL. Exiting."
$ exit