procedure tpu$local_init
ber$main_window := '';
endprocedure;
procedure eve_split_window
local
	wtop,
	wlength,
	ntop,
	nlength,
	nwindow,
	nbuffer;
!
! Check if current window is ber$main_window; if so, do eve_noonly instead
!
if current_window = ber$main_window then
  eve_noonly;
  message("ONLY window unmapped; cannot split that window.");
  return;
endif;
!
! If this is the first time we are splitting the main window there is some
! special stuff to do: 
! use the eve_two_windows procedure to set up the eve$main, eve$top, and
! eve$bottom window variables because they are used by so much else.
!
if eve$x_number_of_windows = 1 then
  eve_two_windows;
  eve_get_file("");
  return;
endif;
!
! The first time executed we never go past the RETURN above
!
wtop := get_info(current_window,"visible_top");
wlength := get_info(current_window,"visible_length");
if wlength <= 3 then
	message("Window too small to split.");
	return;
endif;

nbuffer := current_buffer;
nlength := (wlength + 1)/ 2;
wlength := wlength - nlength;
ntop := wtop + wlength ;
nwindow := create_window(ntop, nlength, ON);
map(nwindow,nbuffer);
position(nwindow);
eve_get_file("");
eve$x_number_of_windows := eve$x_number_of_windows + 1;
endprocedure;