! Write the selected region to a specified file.
!
! Parameters:
!
!	write_file_name		! String containing file name - input

procedure eve_extract_to_file (write_file_name)

local write_result,		! File name string returned by write_file
      reply,
      mess,
      output_file_name;		! Local version of write_file_name

if (eve$x_select_position = 0) then
   message("No text selected for extract");
   return;
endif;

if get_info(current_buffer,"no_write") then
    mess := fao("!AS set NOWRITE. Write anyhow? ",
		get_info(current_buffer,"name"));
    reply := read_line(mess);
    edit(reply, UPPER);
    if substr(reply,1,1) = "Y" then
        eve_set_write;
    else return;
    endif;
endif;

output_file_name := write_file_name;

if output_file_name = eve$kt_null then
	output_file_name := read_line("Name for file? ");
	if output_file_name = eve$kt_null then 
	    output_file_name := "file.txt";
	    message("Using default name FILE.TXT");
	endif;
endif;

! Flesh out with full file spec, using default device and directory
! if they are defined.
if get_info(eve$default_dir,"type") = UNSPECIFIED then
	eve$default_dir := eve$kt_null;
endif;
output_file_name := file_parse (output_file_name,eve$default_dir);

write_result := write_file (select_range, output_file_name);
position(end_of(select_range));
move_horizontal(1);
eve$x_select_position := 0;	! Cancel selection
endprocedure;
procedure tpu$local_init
         eve$arg1_extract_to_file := eve$arg1_get_file;
endprocedure;