;+
;     FILE NAME:  C_T_S.MAR
;        AUTHOR:  Scott W. Cracas
; CREATION DATE:  April 1, 1986
; REVISION DATE:  June 7, 1986
; REVISION DATE:  August 12, 1986
;      LOCATION:  HSTC
;    MAIN FRAME:  VAX 11/780
;        SYSTEM:  VAX/VMS V4.1     (created)
;        SYSTEM:  VAX/VMS V4.4     (2nd revision)
;      LANGUAGE:  VAX MACRO ASSEMBLER
;   DESCRIPTION:  Console Time Stamp
; ---------------------------------------------------------------------
;-

	.title	C_T_S
	.ident	"V3.0"
	.sbttl	data - main data
	.psect	data	noexe,rd,wrt

	$brkdef

scr_width = 132
BEL = 7

term:           .ascii          "OPA0:"
term_len =	.-term
term_desc:	.long	term_len
		.long	term
time_buff:	.ascii	<BEL><BEL>"T I M E  S T A M P"
space:
		.repeat scr_width - <space - time_buff> ; create spaces
		.ascii	" "
		.endr
time_len =	.-time_buff
day_position =  .-35			; position in time_buff to put day.
time_desc:	.long	17	        ; descriptor block for time buffer
		.long	time_buff + time_len - 17
message_desc:	.long	time_len        ; descriptor block for message buffer
		.long	time_buff
rate:		.ascid	"0 00:30:00.00"
delta_rate:	.blkq	1
time_arglist:	.long	1
		.long	time_desc
days:		.ascii	"Sunday          Monday          Tuesday         "
		.ascii	"Wednesday       Thursday        Friday          "
		.ascii	"Saturday        "

	.page
	.sbttl	main line code
	.psect	code,exe,rd,nowrt
	.entry	time_stamp,^m<>

	$bintim_s-			; convert ASCII delta time to binary
	   timbuf = rate, -		; delta time
    	   timadr = delta_rate
	$schdwk_s-			; schedule wake-ups every delta time
	   daytim = delta_rate, -	; intervals
	   reptim = delta_rate

10$:	callg	time_arglist,g^lib$date_time ; get the date and time
	calls	#0,g^juldate		; get the current day 1 - 7
	clrl	r10			; clear register 10
	ashl	#4,r0,r10		; find starting position in days array
	movc3	#16,days[r10],time_buff+88 ; move day name to time buffer
	$brkthru_s-			; broadcast to operator's console (OPA0)
	   msgbuf = message_desc,-
	   sendto = term_desc,-
	   sndtyp = #brk$c_device
	blbc r0,error
	$hiber_s			; wait for scheduled time interval
	brb	10$
error:	ret
	.end	time_stamp