DELETE MORTGAGE;
REDEFINE PROCEDURE MORTGAGE
DECLARE APR USAGE REAL EDIT_STRING IS Z(2)9V99.
DECLARE BALANCE USAGE REAL EDIT_STRING IS Z(9)9V99.
DECLARE TERM USAGE INTEGER EDIT_STRING IS Z9.
DECLARE PERIODS COMPUTED BY TERM * 12.
DECLARE IPP COMPUTED BY APR / 1200.
DECLARE POWER USAGE REAL.
DECLARE MONTHLY COMPUTED BY ((IPP * BALANCE) / (1 - (1 / POWER))).
DECLARE TOTALPI COMPUTED BY MONTHLY * PERIODS.
DECLARE TOTALI COMPUTED BY TOTALPI - BALANCE.
!
APR = 13.5;
BALANCE = 50000;
TERM = 30;
!
APR = *."annual percentage rate <13.5>"
!
WHILE APR NE 0 BEGIN
    BALANCE = *."the mortgage amount <50000>"
    TERM    = *."the length of the loan <30>"
!
    POWER = IPP + 1
!
    REPEAT PERIODS - 1 BEGIN		! or use the FN$POWER function
	POWER  = POWER * (IPP + 1)	! to replace this code
    END
!
    PRINT SKIP 4, "Term is ", FORMAT (TERM) USING Z9, "years"
    PRINT "Annual percentage rate is ", FORMAT (APR) USING Z9V99, "%"
    PRINT "Monthly payment is ", FORMAT (MONTHLY) USING $(5)V99
    PRINT "Principal is ", FORMAT (BALANCE) USING $(9)V99
    PRINT "Total interest is ", FORMAT (TOTALI) USING $(9)V99
!
    APR = 13.5;
    APR = *."annual % rate, use 0 to exit <13.5>"
    BALANCE = 50000;
    TERM = 30;
END
END_PROCEDURE