function long build_form_itmlist

!labels
!form_name_spec - Control is transferred to this label if an error occurred
!		  when a error occurs when testing if the form name is numeric.

!constants
%include "$jbcmsgdef" %from %library "sys$library:basic$starlet.tlb"
%include "$quidef" %from %library "sys$library:basic$starlet.tlb"
%include "$smgdef" %from %library "sys$library:basic$starlet.tlb"
%include "$smgmsg" %from %library "sys$library:basic$starlet.tlb"
%include "smg$routines" %from %library "sys$library:basic$starlet.tlb"
%include "$sjcdef" %from %library "sys$library:basic$starlet.tlb"
%include "$ssdef" %from %library "sys$library:basic$starlet.tlb"

!types

!variables
declare long			sys_status, msg_dpid, form_number,	&
				error_flag
declare string			operation, form_name_str
common (build) string		form_name = 31%
%include "jobctl.bas"

!procedures

!functions
external long function		set_que_entries( word by ref,		&
						 string by desc ),	&
				reload_que,				&
				window_message( string, long, long ),	&
				window_input( string, string, long )

jbclist(3%)::buflen = 31%
jbclist(3%)::itmcod = sjc$_form_name
jbclist(3%)::bufadr = loc(form_name)
jbclist(3%)::retadr = 0%
jbclist(4%)::buflen = 0%
jbclist(4%)::itmcod = 0%
jbclist(4%)::bufadr = 0%
jbclist(4%)::retadr = 0%

sys_status = window_input( "Form Name: ", form_name_str, 31% )
if (sys_status and 1%) = 0% then
    call lib$signal( sys_status by value )
end if

if form_name_str = "" then
    sys_status = window_message( "No change. Hit any key to continue...", &
				 1%, msg_dpid )
    if (sys_status and 1%) = 0% then
	call lib$signal( sys_status by value )
    end if
    build_form_itmlist = ss$_normal
    exit function
end if

when error in
    form_number = val(form_name_str)
    error_flag = 0%
use
    error_flag = -1
    continue form_name_spec
end when

if error_flag = 0% then
    jbclist(3%)::buflen = 4%
    jbclist(3%)::itmcod = sjc$_form_number
    jbclist(3%)::bufadr = loc(form_number)
else
    if edit$(form_name_str, 32%) = "DEFAULT" then
	form_number = 0%
	jbclist(3%)::buflen = 4%
	jbclist(3%)::itmcod = sjc$_form_number
	jbclist(3%)::bufadr = loc(form_number)
    end if
end if

form_name_spec:
form_name = space$(len(form_name))
form_name = form_name_str

operation = " Changing form to " + form_name_str + " for job "
sys_status = set_que_entries( sjc$_alter_job by ref, operation by desc )
if (sys_status and 1%) = 0% then
    call lib$signal( sys_status by value )
end if

sys_status = reload_que
if (sys_status and 1%) = 0% then
    call lib$signal( sys_status by value )
end if

build_form_itmlist = sys_status

end function