function long build_priority_itmlist

!labels
! get_priority - opens window and ask for a new priority value.

!constants
%include "$jbcmsgdef" %from %library "sys$library:basic$starlet.tlb"
%include "$quidef" %from %library "sys$library:basic$starlet.tlb"
%include "$smgdef" %from %library "sys$library:basic$starlet.tlb"
%include "$smgmsg" %from %library "sys$library:basic$starlet.tlb"
%include "smg$routines" %from %library "sys$library:basic$starlet.tlb"
%include "$sjcdef" %from %library "sys$library:basic$starlet.tlb"
%include "$ssdef" %from %library "sys$library:basic$starlet.tlb"

!types

!variables
declare long			sys_status, msg_dpid
declare string			operation, priority_str
%include "jobctl.bas"

!procedures

!functions
external long function		set_que_entries( word by ref,		&
						 string by desc ),	&
				reload_que,				&
				window_message( string, long, long ),	&
				window_input( string, string, long )

jbclist(3%)::buflen = 4%
jbclist(3%)::itmcod = sjc$_priority
jbclist(3%)::bufadr = loc(priority)
jbclist(3%)::retadr = 0%
jbclist(4%)::buflen = 0%
jbclist(4%)::itmcod = 0%
jbclist(4%)::bufadr = 0%
jbclist(4%)::retadr = 0%

get_priority:
sys_status = window_input( "Priority: ", priority_str, 3% )
if (sys_status and 1%) = 0% then
    call lib$signal( sys_status by value )
end if

if priority_str = "" then
    sys_status = window_message( "No change. Hit any key to continue...", &
				 1%, msg_dpid )
    if (sys_status and 1%) = 0% then
	call lib$signal( sys_status by value )
    end if
    build_priority_itmlist = ss$_normal
    exit function
end if

when error in
    priority = val(priority_str)
use
    sys_status = window_message( "Invalid number. Hit any key to continue...", &
				 1%, msg_dpid )
    if (sys_status and 1%) = 0% then
	call lib$signal( sys_status by value )
    end if
    continue get_priority
end when

operation = " Changing priority to " + priority_str + " for job "
sys_status = set_que_entries( sjc$_alter_job by ref, operation by desc )
if (sys_status and 1%) = 0% then
    call lib$signal( sys_status by value )
end if

sys_status = reload_que
if (sys_status and 1%) = 0% then
    call lib$signal( sys_status by value )
end if

build_priority_itmlist = sys_status

end function