$!
$! This command procedure is run prior to starting up the security auditing
$! server process.  Its purpose is to mount or define any disks which will be
$! used to hold security auditing log files (primarily the system security
$! audit journal file) or local security archive files.
$!
$!========================================================================
$! SITE SPECIFIC PARAMETERS
$!========================================================================
$ site_name = f$trnlnm("SITE_NAME","lnm$system","executive")
$ if site_name .eqs."" then $ site_name = "Your_Site_Name_Here"
$!
$! Directory Root for the Security Audit Files
$!
$ security_audit_root = "Security_Journal_Disk:[Audit_Directory.]"
$!
$! Set the archive type to A, B, or C
$!
$! Type C should only be used when the AUDIT_SERVER code is modified to 
$! support shared access to a cluster common security audit archive file.
$!
$ archive_type = "B"
$!
$!========================================================================
$!
$! Get the node name into a symbol
$!
$ if f$type(my_node).eqs."" then $ @utl:getnode my_node
$!
$ defgrp = "define/table=lnm$group_000001/executive_mode"
$ defsys = "define/system/executive_mode"
$ credir = "create/directory/own=parent/prot=(s:rw,o:rw,g,w)"
$!
$ security_audit_db_dir = "security_audit_root:[db]"
$ security_audit_device = -
	f$parse(security_audit_db_dir,,,"device","syntax_only")
$!
$! see if the device is mounted already -- if not, then do it now.
$!
$ if .not.f$getdvi(security_audit_device,"exists")
$ then
$	@sys$startup:loc$shadow_mount
$ else
$ if .not.f$getdvi(security_audit_device,"mnt")
$ then
$	@sys$startup:loc$shadow_mount
$ endif
$ endif
$!
$! Make sure the logical name(s) are defined
$!
$ defgrp audit_archive_type 'archive_type'
$ defsys security_audit_root 'security_audit_root'/translation=concealed
$!
$! Make sure the directory exists
$!
$ if f$parse(security_audit_db_dir).eqs."" 
$ then 
$	create/directory 'security_audit_db_dir'/log-
	/prot=(s:rw,o:rw,g,w)/own=[1,1]
$ endif
$!
$! Construct the server database file name
$!
$ if archive_type.eqs."A" .or. archive_type.eqs."C"
$ then
$	audit_file = security_audit_db_dir+site_name+"_audit_server.dat"
$ else
$ if archive_type.eqs."B" 
$ then 
$	audit_file = security_audit_db_dir+my_node+"_audit_server.dat"
$ endif
$ endif
$!
$! Define the audit database now
$!
$ defsys audit_server 'audit_file'
$!
$! Make sure the other directories exist
$!
$ if f$parse("security_audit_root:[journal]").eqs."" then -
$	credir security_audit_root:[journal]
$ if f$parse("security_audit_root:[archive]").eqs."" then -
$	credir security_audit_root:[archive]
$ if f$parse("security_audit_root:[work]").eqs."" then -
$	credir security_audit_root:[work]
$!
$!Last Modified:  19-JAN-1990 18:32:21.96, By: RLB