MODULE TPUPlus_LINE IDENT "901210"
!   Replaced code with Steve Travis's code found in DEC PROFESSIONAL
!   Vol 9, #10, December 1990, pg. 70-74
!MODULE TPUPlus_LINE IDENT "900409"
!   Original version used Steve Graham's code
!****************************************
!
!   PROCEDURE PCE_TOGGLE_LINEDRAW
!   PROCEDURE EVE_SET_LINEDRAWING
!   PROCEDURE EVE_SET_NOLINEDRAWING
!   PROCEDURE SCT_GFILE
!   PROCEDURE SCT_GSET
!   PROCEDURE EVE$LINEDRAW_STATUS_FIELD (THE_LENGTH, THE_FORMAT)
!   PROCEDURE SCT_GKEYS
!
!****************************************

!****************************************
PROCEDURE PCE_TOGGLE_LINEDRAW

if (get_info (pce$linedraw_mode, "type") = UNSPECIFIED) then
    pce$linedraw_mode := "NORMAL";
endif;

if pce$linedraw_mode = "LINEDRAW" then
    eve_set_nolinedrawing;
else
    eve_set_linedrawing;
endif;

ENDPROCEDURE;

!****************************************
PROCEDURE EVE_SET_LINEDRAWING

add_key_map (eve$x_key_map_list, "first", rhs$x_linedraw_keys);
pce$linedraw_mode := "LINEDRAW";
sct_gset;
message ("Numeric keys will now draw lines using line drawing set");
eve$update_status_lines;

ENDPROCEDURE;

!****************************************
PROCEDURE EVE_SET_NOLINEDRAWING

remove_key_map (eve$x_key_map_list, rhs$x_linedraw_keys, ALL);
pce$linedraw_mode := "NORMAL";
message ("Numeric keys are now reset to their original definitions");
eve$update_status_lines;

ENDPROCEDURE;

!****************************************
PROCEDURE SCT_GFILE

!local g_mark;

on_error
    return;
endon_error;

g_buffer := create_buffer ('g_file', 'pub:g_esc.dat');
set (system, g_buffer);

ENDPROCEDURE;

!****************************************
PROCEDURE SCT_GSET

local g_mark;

g_mark := mark (none);
set (screen_update, off);
write_file (g_buffer, 'sys$output');
message ("");
message ("");
set (screen_update, on);
position (g_mark);

ENDPROCEDURE;

!****************************************
PROCEDURE EVE$LINEDRAW_STATUS_FIELD (THE_LENGTH, THE_FORMAT)

if pce$linedraw_mode = "LINEDRAW" then
    return (fao (the_format, "Line Draw"));
else
    return "";
endif;

ENDPROCEDURE;

!****************************************
PROCEDURE SCT_GKEYS

create_key_map  ("rhs$line_keys");

define_key ("copy_text (ascii (236))", kp7,     "", "rhs$line_keys");
define_key ("copy_text (ascii (247))", kp8,     "", "rhs$line_keys");
define_key ("copy_text (ascii (235))", kp9,     "", "rhs$line_keys");
define_key ("copy_text (ascii (244))", kp4,     "", "rhs$line_keys");
define_key ("copy_text (ascii (238))", kp5,     "", "rhs$line_keys");
define_key ("copy_text (ascii (245))", kp6,     "", "rhs$line_keys");
define_key ("copy_text (ascii (237))", kp1,     "", "rhs$line_keys");
define_key ("copy_text (ascii (246))", kp2,     "", "rhs$line_keys");
define_key ("copy_text (ascii (234))", kp3,     "", "rhs$line_keys");
define_key ("copy_text (ascii (241))", minus,   "", "rhs$line_keys");
define_key ("copy_text (ascii (248))", comma,   "", "rhs$line_keys");

ENDPROCEDURE;

rhs$x_linedraw_keys := "rhs$line_keys";
sct_gfile;

ENDMODULE;

sct_gkeys;
compile("procedure sct_gkeys endprocedure");
!
!  мссссссссчссссссссл
!  ш        ш        ш
!  ш        ш        ш
!  фссссссссоссссссссх
!  ш        ш        ш
!  ш        ш        ш
!  нссссссссцсссссссск
!