From:	MERC::"uunet!CRVAX.SRI.COM!RELAY-INFO-VAX" 18-MAR-1993 02:38:14.79
To:	Info-VAX@KL.SRI.COM
CC:	
Subj:	RE: String Manputilation


In article <1993Mar18.081808.1@tango.cchs.su.edu.au>, brennan@tango.cchs.su.edu.au (Luke Brennan) writes:
>In article <1o748tINNmt2@gap.caltech.edu>, carl@SOL1.GPS.CALTECH.EDU (Carl J Lydick) writes:

>>>	Seriously people... the masses are *not* gunna make the leap
>>>	to 'lexicals' when they want string manipulations...

>> For those among you as brain-dead as Brennan, I submit the following sesssion

>	LEXICALS Carl, go flagellate yourself with a dictionary and see how
>	the unwashed masses who do NOT have endless hours to wade through
>	the documentation would make this leap in thinking.

BULL$#IT!!!

	You don't need `endless hours' to use the online HELP. As a matter of
	fact, no other operating system is as easy to get information about as
	VMS. The HELP HINTS is absolutely unique and should allways be your 
	first port of call when there is something you don't know how to do.

	And now to the technical contents (to comply with Ehud's rules :-)
	After my signature file you'll find a small command file that defines
	the logical DECW$DISPLAY with the correct TRANSPORT on remote and 
	network	logins.

Cheers


Bernhard
________________________________________________________________________________
Dr Bernhard Fabricius              |
Academic VAX/VMS Support           |  "I am a Bear of Very Little Brain,
Department of Nuclear Physics      |           and long words Bother me."
Australian National University     |
                                   |                           - A.A. Milne
InterNet: BEAR@NUC.ANU.EDU.AU      |
    POSTMASTER@NUC.ANU.EDU.AU      |
$!AUTO-DISPLAY.COM
$!
$!Define DECW$DISPLAY (if undefined), based on the TT_AccPorNam field. 
$!
$!Transport   TT_AccPorNam returns:         Method:
$!--------------------------------------------------------
$!LAT         LAT_<EtherNetAddress>         Use as is
$!TCP/IP      Host: <Node> Port: <Number>   Extract <Node>
$!DECnet      <Node>::<User>                Extract <Node>
$!
$!Bernhard Fabricius, March-1993
$!------------------------------------------------------------------------------
$!
$!Check first to see if display is defined (if so exit).
$if f$trnlnm("DECW$DISPLAY").nes."" then EXIT
$!
$!No, it's not. Try to get node info:
$node=f$getdvi("TT","TT_AccPorNam")
$node=f$element(0,"/",node)		!Ignore LAT terminal servers - they 
$!					!don't have displays anyway...
$!If we get a blank then exit
$if node.eqs."" then goto FAIL
$!
$!Check for LAT
$if f$extract(0,4,node).eqs."LAT_" 
$then 					!Use node name as is
$ node=node+"/TRANSPORT=LAT"		!Append transport qualifier
$else
$!
$!Check for TCP/IP
$ if f$extract(0,5,node).eqs."Host:" 
$ then 
$  node=f$element(1," ",node)		!Get node name (after first space)
$  node=node+"/TRANSPORT=TCPIP"		!Append transport qualifier
$ else
$!
$!Must be DECnet
$  node=f$element(0,":",node)		!Get node name (before first colon)
$ endif					!DECnet transport is default
$endif
$!
$!Do it and announce the fact
$set display/create/node='node
$write sys$output "DECW$DISPLAY defined to be ''node'"
$exit
$!
$FAIL:
$write sys$output "WARNING: DECW$DISPLAY is undefined"
$exit

