$ w:=write sys$output
$ w "M Node   Username     Pid           WS     PhyMem   PagFil"
$ w ""
$ ncntx=""
$ cluster=f$getsyi("CLUSTER_MEMBER")
$ loop1:
$    cntx=0
$    if cluster
$    then
$       csid=f$csid(ncntx)
$       if csid .eqs. "" then goto endloop1
$       node=f$getsyi("NODENAME",,csid)
$       tmp=f$context ("PROCESS",cntx,"NODENAME",node,"EQL")
$    else
$       node=f$getsyi("NODENAME")
$    endif
$    tmp=f$context ("PROCESS",cntx,"USERNAME","*","EQL")
$    loop2:
$       pid=f$pid(cntx)
$       if pid .eqs. "" then goto endloop2
$       mode=f$getjpi(pid,"MODE")
$       mode1=f$extract(0,1,mode)
$       un=f$getjpi(pid,"USERNAME")
$       ws=f$getjpi(pid,"WSSIZE")
$       phymem=f$getjpi(pid,"PPGCNT")+f$getjpi(pid,"GPGCNT")
$       pagfil=f$getjpi(pid,"PGFLQUOTA")-f$getjpi(pid,"PAGFILCNT")
$       w f$fao("!1AS !6AS !12AS !8AS !8SL !8SL !8SL", -
             mode,node,un,pid,ws,phymem,pagfil)
$       goto loop2
$    endloop2:
$    if cluster then goto loop1
$ endloop1:   
$ exit
